Signal Recycling mirror curvature

Utility Functions

RealPart[z_]:=Module[{ImaginaryUnit,a,b},Coefficient[Collect[ComplexExpand[z]/.Complex[a_,b_]->a+b*ImaginaryUnit,ImaginaryUnit],ImaginaryUnit,0]];

ImaginaryPart[z_]:=Module[{ImaginaryUnit,a,b},Coefficient[Collect[ComplexExpand[z]/.Complex[a_,b_]->a+b*ImaginaryUnit,ImaginaryUnit],ImaginaryUnit,1]];

Parameters

Params={L->8.328,LSRCvac->6.662,R->96,λ->1064 (10^(-9)),tITM->25 (10^(-3)),tBS->28 (10^(-3)),n->1.45,k0->2(π/(1064 (10^(-9)))),Lsch->0.05};

L is the average length of RMC (cf. schnupp asymmetry), LSRCvac is the length of SRC, R is the designed ROC for the PRC, λ is the wavelength of the laser, tITM is the thickness of ITMs, tBS is the thickness of BS, n is the index of reflaction of fused silica, k0 is the wave number of the laser, Lsch is the schnupp asymmetry. These parameters are in vacuum numbers.

Thin mirror/BS design

This section is here mainly to calculate the waist size at ITM. The rest is not important.

Waist size at ITM

w0=(((((λ/π))(Sqrt[L(R-L)])))^(1/2))/.Params

This number is used as the reference through out the notebook.

q parameter at ITM

q0=I ((π (w0^2))/λ);

ABCD Matrix for a travel from ITM to RM

T=(({{1, L}, {0, 1}}));

q parameter at RM

qRMv=T.{{q0},{1}};

qRM=(qRMv[[1]]/qRMv[[2]])[[1]];

ROC of RM

RRM=Simplify[1/RealPart[1/qRM]]/.Params

as expected ...

PRC calculation

Geometric path length inside BS

LBS= ((n tBS)/(Sqrt[(n^2)-1/2]));

Effective length of PRC X-arm for Gaussian beam propagation

LPRCX=Lcom-LBS+LBS/n-tITM+tITM/n+Las;

Las is the geometric asymmetry of the Michelson arms

Effectie length of PRC Y-arm for Gaussian beam propagation

LPRCY=Lcom-tITM+tITM/n;

Effective average length of PRC for Gaussian beam propagation

LPRC=Simplify[((LPRCX+LPRCY)/2)];

Average optical length of PRC

Lopt=((2*Lcom+2*tITM (n-1)+LBS(n-1)+Las)/2);

Effective schnupp asymmetry

Lscheff=LBS(n-1)+Las;

Required geometric asymmetry

Las1=Las/.Solve[Lscheff==Lsch/.Params,Las][[1]]

Determine Lcom

We want the average optical length to be the same as the design length in vacuum

Lcom1=Lcom/.Solve[Lopt==L/.Params/.Las->Las1,Lcom][[1]]

Parameter set 2

Params2={Las->Las1, Lcom->Lcom1};

Effective asymmetry for Gaussian beam propagation

LPRCX-LPRCY/.Params/.Params2

ABCD Matrix for one way trip in PRC

P=(({{1, LPRC}, {0, 1}}));

q parameter at RM

qRMv=P.(({{q0}, {1}}));

qRM=(qRMv[[1]]/qRMv[[2]])[[1]];

ROC of RM

RRM=1/Re[1/qRM];

RRM/.Params/.Params2

Beam size at RM

w2=(Sqrt[λ /Im[-1/qRM]/π]);

w2/.Params/.Params2

SRC calculation

SRC lengths for Gaussian Beam Propagation

LSRCX=LcomSRC-2LBS+2LBS/n-tITM+tITM/n+Las;

LSRCY=LcomSRC-LBS+LBS/n-tITM+tITM/n;

LSRC=((LSRCX+LSRCY)/2);

Average optical length of SRC

LSRCopt=((2LcomSRC+3LBS(n-1)+2tITM(n-1)+Las)/2);

Determine LcomSRC

We want the average optical length of SRC to be the designed one

LcomSRC1=LcomSRC/.Solve[LSRCopt==LSRCvac/.Params/.Params2,LcomSRC][[1]];

Params2=Join[Params2,{ LcomSRC->LcomSRC1}];

ABCD Matrix for one way trip in SRC

S=(({{1, LSRC}, {0, 1}}));

q parameter at RM

qSRMv=S.(({{q0}, {1}}));

qSRM=(qSRMv[[1]]/qSRMv[[2]])[[1]];

ROC of RM

RSRM=1/Re[1/qSRM];

RSRM/.Params/.Params2

Beam size at SRM

w2=(Sqrt[λ /Im[-1/qSRM]/π]);

w2/.Params/.Params2

g factor

ABCD matrix for a round trip in SRC

Tsrc=Simplify[(({{1, LSRC}, {0, 1}})).(({{1, 0}, {((-2)/Rm), 1}})).(({{1, LSRC}, {0, 1}}))];

g factor

g=Tr[Tsrc]/2;

Manipulate[g/.Params/.Params2/.Rm->x,{x,50,200}]

Transeverse Mode Interval

γ=ArcCos[g]/π/.Params/.Params2;

Manipulate[γ/.Rm->x,{x,50,250}]

Mode matching

Cavity Waist Size as a function of ROC

q parameter at ITM

q0c=I ((π (w0c^2))/λ);

q parameter at SRM

q2v=S.(({{q0c}, {1}}));

q2=Simplify[(q2v[[1]]/q2v[[2]])[[1]]];

ROC of PRM as a function of the waist size

R2=Simplify[1/RealPart[1/q2/.Params/.Params2]]

Solve it inversely to get the waist size as a function of PRM ROC

w2=w0c/.Solve[R2==Rm/.Params/.Params2,w0c][[4]]

Cavity mode mismaching

Rayleigh range of the designed cavity mode

zr0=((k0 (w0^2))/2)/.Params/.Params2

Rayleigh range of the SRC as a function of SRM ROC

zr2=((k0 (w2^2))/2)/.Params/.Params2

Cavity mode mismatching

ϵ= zr2-zr0;

Mm= ((2 zr0 (Sqrt[1+ϵ/zr0]))/(2 zr0 + ϵ))

Plot[{Mm,0.99},{Rm,50,250}]

Plot[{w2,w0},{Rm,50,250}]

Manipulate[Mm/.Rm->x,{x,50,250}]

More than 99 % of mode matching is achieved when the ROC of PRM is in [70,201] range (unit is in meters).

Conclusion

The actual ROC of the SRM should be 117.125m. The geometric length of the SR-Michelson Y-arm  should be  6.61132m (from the front surface of the SRM to the front surface of ITMY). The SR-Michelson X-arm is 0.0355676 longer than Y-arm. These numbers are geometric length, not optical length. However, the elongation of the geometric beam path by the bending of the light inside the BS is included.
From the mode-mismatching requirement of more than 99%, the tolerance of the ROC of SRM is 117.125 +84/-47 m.
 g-factor goes to 2.0 at SRM ROC=69. So we don't want to have the ROC to be not so small. A reasonable tolerance value would be something like 117.1+50/-20.

LcomSRC1+Las1