Recycling mirror curvature

Utility Functions

RealPart[z_]:=Module[{ImaginaryUnit,a,b},Coefficient[Collect[ComplexExpand[z]/.Complex[a_,b_]->a+b*ImaginaryUnit,ImaginaryUnit],ImaginaryUnit,0]];

ImaginaryPart[z_]:=Module[{ImaginaryUnit,a,b},Coefficient[Collect[ComplexExpand[z]/.Complex[a_,b_]->a+b*ImaginaryUnit,ImaginaryUnit],ImaginaryUnit,1]];

Parameters

Params={L->8.328,R->96,λ->1064 (10^(-9)),tITM->25 (10^(-3)),tBS->28 (10^(-3)),n->1.45,k0->2(π/(1064 (10^(-9)))),Lsch->0.05};

L is the average length of RMC (cf. schnupp asymmetry), R is the designed ROC for the PRC, λ is the wavelength of the laser, tITM is the thickness of ITMs, tBS is the thickness of BS, n is the index of reflaction of fused silica, k0 is the wave number of the laser, Lsch is the schnupp asymmetry. These parameters are in vacuum numbers.

Thin mirror/BS design

Waist size at ITM

w0=(((((λ/π))(Sqrt[L(R-L)])))^(1/2))/.Params

This number is used as the reference through out the notebook.

q parameter at ITM

q0=I ((π (w0^2))/λ);

ABCD Matrix for a travel from ITM to RM

T=(({{1, L}, {0, 1}}));

q parameter at RM

qRMv=T.{{q0},{1}};

qRM=(q1v[[1]]/q1v[[2]])[[1]];

ROC of RM

RRM=Simplify[1/RealPart[1/qRM]]

as expected ...

Thick ITM/BS case

Geometric path length inside BS

LBS= ((n tBS)/(Sqrt[(n^2)-1/2]));

Effective length of PRC X-arm for Gaussian beam propagation

LPRCX=Lcom-LBS+LBS/n-tITM+tITM/n+Las;

Las is the geometric asymmetry of the Michelson arms

Effectie length of PRC Y-arm for Gaussian beam propagation

LPRCY=Lcom-tITM+tITM/n;

Effective average length of PRC for Gaussian beam propagation

LPRC=Simplify[((LPRCX+LPRCY)/2)];

Average optical length of PRC

Lopt=((2*Lcom+2*tITM (n-1)+LBS(n-1)+Las)/2);

Effective schnupp asymmetry

Lscheff=LBS(n-1)+Las;

Required geometric asymmetry

Las1=Las/.Solve[Lscheff==Lsch/.Params,Las][[1]]

Determine Lcom

We want the average optical length to be the same as the design length in vacuum

Lcom1=Lcom/.Solve[Lopt==L/.Params/.Las->Las1,Lcom][[1]]

Parameter set 2

Params2={Las->Las1, Lcom->Lcom1};

Effective asymmetry for Gaussian beam propagation

LPRCX-LPRCY/.Params/.Params2

ABCD Matrix for one way trip in PRC

S=(({{1, LPRC}, {0, 1}}));

q parameter at RM

qRMv=S.(({{q0}, {1}}));

qRM=(qRMv[[1]]/qRMv[[2]])[[1]];

ROC of RM

RRM=1/Re[1/qRM];

RRM/.Params/.Params2

Beam size at RM

w2=(Sqrt[λ /Im[-1/qRM]/π]);

w2/.Params/.Params2

g factor

ABCD matrix for a round trip in PRC

Tprc=Simplify[(({{1, LPRC}, {0, 1}})).(({{1, 0}, {((-2)/Rm), 1}})).(({{1, LPRC}, {0, 1}}))];

g factor

g=Tr[Tprc]/2;

Manipulate[g/.Params/.Params2/.Rm->x,{x,30,200}]

Transeverse Mode Interval

γ=ArcCos[g]/π/.Params/.Params2;

Manipulate[γ/.Rm->x,{x,30,200}]

γ is 0.189655 when the ROC of PRM is 96.3. It becomes 0.2 at ROC= 86.9 and becomes 0.15 at ROC=152.2.
So it seems like dangerous to have a slightly smaller ROC.

Mode matching

Cavity Waist Size as a function of ROC

q parameter at ITM

q0c=I ((π (w0c^2))/λ);

q parameter at PRM

q2v=S.(({{q0c}, {1}}));

q2=Simplify[(q2v[[1]]/q2v[[2]])[[1]]];

ROC of PRM as a function of the waist size

R2=Simplify[1/RealPart[1/q2/.Params/.Params2]]

Solve it inversely to get the waist size as a function of PRM ROC

w2=w0c/.Solve[R2==Rm/.Params/.Params2,w0c][[4]]

Cavity mode mismaching

Rayleigh range of the designed cavity mode

zr0=((k0 (w0^2))/2)/.Params/.Params2

Rayleigh range of the PRC as a function of RM ROC

zr2=((k0 (w2^2))/2)/.Params/.Params2

Cavity mode mismatching

ϵ= zr2-zr0;

Mm= ((2 zr0 (Sqrt[1+ϵ/zr0]))/(2 zr0 + ϵ))

Plot[{Mm,0.99},{Rm,30,200}]

Plot[{w2,w0},{Rm,30,200}]

Manipulate[Mm/.Rm->x,{x,30,200}]

More than 99 % of mode matching is achieved when the ROC of PRM is in [59,163] range (unit is in meters).

Conclusion

The actual ROC of the PRM should be 96.3m. The PR-Michelson Y-arm length should be  8.29175m (from the front surface of the PRM to the front surface of ITMY). The PR-Michelson X-arm should be 0.0355676 longer than Y-arm. These numbers are geometric length, not optical length. However, X-arm length includes the elongation of the geometric beam path by the bending of the light inside the BS.
From the mode-mismatching requirement of more than 99%, the tolerance of the ROC of PRM is 96.3 +67/-37 m.
However, g-factor consideration shows that the transeverse mode interval becomes 0.2 when the ROC is 86.9. Therefore, it is safer to require zero tolerance towards smaller ROC. So it is recommended  to require something like ROC = 96.3 +50/-0 m if possible.